Ⅰ 單片機的，關於可調時鍾的
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 定時器T0、T1溢出周期為50MS,T0為秒計數用,T1為調整時閃爍用，
; P3.5為調整按鈕,P0口 為字元輸出口,P2口為位選端,採用共陽顯示管。
; 時間調整方法：按P3.5未超過1s進入省電模式攔芹吵，數碼管不亮，內部時鍾計時
; 按P3.5超過1s進入調整簡侍模式,要調整的時間會閃動，此時，按下P3.5超過0.5S，
; 進入下位調整,按下P3.5未超過0.5S，當前位加一
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 中斷入口程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ORG 0000H ;程序執行開始地址
LJMP START ;跳到標號START執行
ORG 0003H ;外中斷0中斷程序首乎入口
RETI ;外中斷0中斷返回
ORG 000BH ;定時器T0中斷程序入口
LJMP INTT0 ;跳至INTTO執行
ORG 0013H ;外中斷1中斷程序入口
RETI ;外中斷1中斷返回
ORG 001BH ;定時器T1中斷程序入口
LJMP INTT1 ;跳至INTT1執行
ORG 0023H ;串列中斷程序入口地址
RETI ;串列中斷程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 主 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
START: MOV R0,#70H ;清70H-7AH共11個內存單元
MOV R7,#0BH ;
CLEARDISP: MOV @R0,#00H ;
INC R0 ;
DJNZ R7,CLEARDISP ;
MOV 20H,#00H ;清20H（標志用）
MOV 7AH,#0AH ;放入""熄滅符""數據
MOV TMOD,#11H ;設T0、T1為16位定時器
MOV TL0,#0B0H ;50MS定時初值（T0計時用）
MOV TH0,#3CH ;50MS定時初值
MOV TL1,#0B0H ;50MS定時初值（T1閃爍定時用）
MOV TH1,#3CH ;50MS定時初值
SETB EA ;總中斷開放
SETB ET0 ;允許T0中斷
SETB TR0 ;開啟T0定時器
MOV R4,#14H ;1秒定時用初值（50MS×20）
START1: LCALL DISPLAY ;調用顯示子程序
JNB P3.5,SETMM1 ;P3.5口為0時轉時間調整程序
SJMP START1 ;P3.5口為1時跳回START1
SETMM1: LJMP SETMM ;轉到時間調整程序SETMM
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 1秒計時程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T0中斷服務程序
INTT0: PUSH ACC ;累加器入棧保護
PUSH PSW ;狀態字入棧保護
CLR ET0 ;關T0中斷允許
CLR TR0 ;關閉定時器T0
MOV A,#0B7H ;中斷響應時間同步修正
ADD A,TL0 ;低8位初值修正
MOV TL0,A ;重裝初值（低8位修正值）
MOV A,#3CH ;高8位初值修正
ADDC A,TH0 ;
MOV TH0,A ;重裝初值（高8位修正值）
SETB TR0 ;開啟定時器T0
DJNZ R4, OUTT0 ;20次中斷未到中斷退出
ADDSS: MOV R4,#14H ;20次中斷到（1秒）重賦初值
MOV R0,#71H ;指向秒計時單元（71H-72H）
ACALL ADD1 ;調用加1程序（加1秒操作）
MOV A,R3 ;秒數據放入A（R3為2位十進制數組合）
CLR C ;清進位標志
CJNE A,#60H,ADDMM ;
ADDMM: JC OUTT0 ;小於60秒時中斷退出
ACALL CLR0 ;大於或等於60秒時對秒計時單元清0
MOV R0,#77H ;指向分計時單元（76H-77H）
ACALL ADD1 ;分計時單元加1分鍾
MOV A,R3 ;分數據放入A
CLR C ;清進位標志
CJNE A,#60H,ADDHH ;
ADDHH: JC OUTT0 ;小於60分時中斷退出
ACALL CLR0 ;大於或等於60分時分計時單元清0
MOV R0,#79H ;指向小時計時單元（78H-79H）
ACALL ADD1 ;小時計時單元加1小時
MOV A,R3 ;時數據放入A
CLR C ;清進位標志
CJNE A,#24H,HOUR ;
HOUR: JC OUTT0 ;小於24小時中斷退出
ACALL CLR0 ;大於或等於24小時小時計時單元清0
OUTT0: MOV 72H,76H ;中斷退出時將分、時計時單元數據移
MOV 73H,77H ;入對應顯示單元
MOV 74H,78H ;
MOV 75H,79H ;
POP PSW ;恢復狀態字（出棧）
POP ACC ;恢復累加器
SETB ET0 ;開放T0中斷
RETI ;中斷返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 閃動調時 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T1中斷服務程序，用作時間調整時調整單元閃爍指示
INTT1: PUSH ACC ;中斷現場保護
PUSH PSW ;
MOV TL1, #0B0H ;裝定時器T1定時初值
MOV TH1, #3CH ;
DJNZ R2,INTT1OUT ;0.3秒未到退出中斷（50MS中斷6次）
MOV R2,#06H ;重裝0.3秒定時用初值
CPL 02H ;0.3秒定時到對閃爍標志取反
JB 02H,FLASH1 ;02H位為1時顯示單元""熄滅""
MOV 72H,76H ;02H位為0時正常顯示
MOV 73H,77H ;
MOV 74H,78H ;
MOV 75H,79H ;
INTT1OUT: POP PSW ;恢復現場
POP ACC ;
RETI ;中斷退出
FLASH1: JB 01H,FLASH2 ;01H位為1時，轉小時熄滅控制
MOV 72H,7AH ;01H位為0時，""熄滅符""數據放入分
MOV 73H,7AH ;顯示單元（72H-73H），將不顯示分數據
MOV 74H,78H ;
MOV 75H,79H ;
AJMP INTT1OUT ;轉中斷退出
FLASH2: MOV 72H,76H ;01H位為1時，""熄滅符""數據放入小時
MOV 73H,77H ;顯示單元（74H-75H），小時數據將不顯示
MOV 74H,7AH ;
MOV 75H,7AH ;
AJMP INTT1OUT ;轉中斷退出
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 加1子 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ADD1: MOV A,@R0 ;取當前計時單元數據到A
DEC R0 ;指向前一地址
SWAP A ;A中數據高四位與低四位交換
ORL A,@R0 ;前一地址中數據放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十進制調整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位變0
MOV @R0,A ;放回前一地址單元
MOV A,R3 ;取回R3中暫存數據
INC R0 ;指向當前地址單元
SWAP A ;A中數據高四位與低四位交換
ANL A,#0FH ;高四位變0
MOV @R0,A ;數據放入當削地址單元中
RET ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 清零程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;對計時單元復零用
CLR0: CLR A ;清累加器
MOV @R0,A ;清當前地址單元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址單元清0
RET ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 時鍾調整程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;當調時按鍵按下時進入此程序
SETMM: cLR ET0 ;關定時器T0中斷
CLR TR0 ;關閉定時器T0
LCALL DL1S ;調用1秒延時程序
JB P3.5,CLOSEDIS ;鍵按下時間小於1秒，關閉顯示（省電）
MOV R2,#06H ;進入調時狀態，賦閃爍定時初值
SETB ET1 ;允許T1中斷
SETB TR1 ;開啟定時器T1
SET2: JNB P3.5,SET1 ;P3.5口為0（鍵未釋放），等待
SETB 00H ;鍵釋放，分調整閃爍標志置1
SET4: JB P3.5,SET3 ;等待鍵按下
LCALL DL05S ;有鍵按下，延時0.5秒
JNB P3.5,SETHH ;按下時間大於0.5秒轉調小時狀態
MOV R0,#77H ;按下時間小於0.5秒加1分鍾操作
LCALL ADD1 ;調用加1子程序
MOV A,R3 ;取調整單元數據
CLR C ;清進位標志
CJNE A,#60H,HHH ;調整單元數據與60比較
HHH: JC SET4 ;調整單元數據小於60轉SET4循環
LCALL CLR0 ;調整單元數據大於或等於60時清0
CLR C ;清進位標志
AJMP SET4 ;跳轉到SET4循環
CLOSEDIS: SETB ET0 ;省電（LED不顯示）狀態。開T0中斷
SETB TR0 ;開啟T0定時器（開時鍾）
CLOSE: JB P3.5,CLOSE ;無按鍵按下，等待。
LCALL DISPLAY ;有鍵按下，調顯示子程序延時削抖
JB P3.5,CLOSE ;是干擾返回CLOSE等待
WAITH: JNB P3.5,WAITH ;等待鍵釋放
LJMP START1 ;返回主程序（LED數據顯示亮）
SETHH: CLR 00H ;分閃爍標志清除（進入調小時狀態）
SETHH1: JNB P3.5,SET5 ;等待鍵釋放
SETB 01H ;小時調整標志置1
SET6: JB P3.5,SET7 ;等待按鍵按下
LCALL DL05S ;有鍵按下延時0.5秒
JNB P3.5,SETOUT ;按下時間大於0.5秒退出時間調整
MOV R0,#79H ;按下時間小於0.5秒加1小時操作
LCALL ADD1 ;調加1子程序
MOV A,R3 ;
CLR C ;
CJNE A,#24H,HOUU ;計時單元數據與24比較
HOUU: JC SET6 ;小於24轉SET6循環
LCALL CLR0 ;大於或等於24時清0操作
AJMP SET6 ;跳轉到SET6循環
SETOUT: JNB P3.5,SETOUT1 ;調時退出程序。等待鍵釋放
LCALL DISPLAY ;延時削抖
JNB P3.5,SETOUT ;是抖動，返回SETOUT再等待
CLR 01H ;清調小時標志
CLR 00H ;清調分標志
CLR 02H ;清閃爍標志
CLR TR1 ;關閉定時器T1
CLR ET1 ;關定時器T1中斷
SETB TR0 ;開啟定時器T0
SETB ET0 ;開定時器T0中斷（計時開始）
LJMP START1 ;跳回主程序
SET1: LCALL DISPLAY ;鍵釋放等待時調用顯示程序（調分）
AJMP SET2 ;防止鍵按下時無時鍾顯示
SET3: LCALL DISPLAY ;等待調分按鍵時時鍾顯示用
AJMP SET4
SET5: LCALL DISPLAY ;鍵釋放等待時調用顯示程序（調小時）
AJMP SETHH1 ;防止鍵按下時無時鍾顯示
SET7: LCALL DISPLAY ;等待調小時按鍵時時鍾顯示用
AJMP SET6
SETOUT1: LCALL DISPLAY ;退出時鍾調整時鍵釋放等待
AJMP SETOUT ;防止鍵按下時無時鍾顯示
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 顯示程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 顯示數據在70H-75H單元內，用六位LED共陽數碼管顯示，P1口輸出段碼數據，P3口作
; 掃描控制，每個LED數碼管亮1MS時間再逐位循環。
DISPLAY: MOV R1,#70H ;指向顯示數據首址
MOV R5,#0FEH ;掃描控制字初值
PLAY: MOV A,R5 ;掃描字放入A
MOV P2,A ;從P3口輸出
MOV A,@R1 ;取顯示數據到A
MOV DPTR,#TAB ;取段碼表地址
MOVC A,@A+DPTR ;查顯示數據對應段碼
MOV P0,A ;段碼放入P1口
LCALL DL1MS ;顯示1MS
INC R1 ;指向下一地址
MOV A,R5 ;掃描控制字放入A
JNB ACC.5,ENDOUT ;ACC.5=0時一次顯示結束
RL A ;A中數據循環左移
MOV R5,A ;放回R5內
AJMP PLAY ;跳回PLAY循環
ENDOUT: SETB P2.5 ;一次顯示結束，P3口復位
MOV P0,#0FFH ;P1口復位
RET ;子程序返回
TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
;共陽段碼表 ""0"""" 1"""" 2"" "" 3"" ""4"" ""5"" ""6"" ""7"" ""8"" ""9""""不亮""
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 延時程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1MS延時程序，LED顯示程序用
DL1MS: MOV R6,#14H
DL1: MOV R7,#19H
DL2: DJNZ R7,DL2
DJNZ R6,DL1
RET
;20MS延時程序，採用調用顯示子程序以改善LED的顯示閃爍現象
DS20MS: ACALL DISPLAY
ACALL DISPLAY
ACALL DISPLAY
RET
;延時程序，用作按鍵時間的長短判斷
DL1S: LCALL DL05S
LCALL DL05S
RET
DL05S: MOV R3,#20H ;8毫秒*32=0.196秒
DL05S1: LCALL DISPLAY
DJNZ R3,DL05S1
RET
END ;程序結束
Ⅱ 設計用單片機 P1 口控制 1 位共陰極 LED 。按鍵 1 按下，循環顯示 0 ～ 5 ，按鍵 2
1．試驗任務
本實驗實現的是數襲宏字鍾，分別在6位數大唯碼管上顯示分時秒，並且可以通過第1個獨立按鍵（k1）進行時間調整，即如果按鍵按下超過0.5秒則進行時間分秒的調整。
2．實驗目的
（1）將已掌握的單片機理論知識和實驗技能連貫起來，進行綜合課題的設計
（2）提高單片機應用系統的獨立設計和編程能力，同時，已電子時鍾為基礎，可以延伸出許多有前途的課題。
3．實驗原理
首先用單片機內部定時器/計數器t0產生50ms作為時鍾的最小記時單位，每到50ms，t0中斷溢出，在中斷服務程序中用軟體計數器記數，當記數到20次時，即為1s，使秒單元71h的內容加1，同時使50ms單元復位；當秒單元的內容為60時，使分單元的內容加1，同時秒單元復位，同理，當分單元的內拍仿冊容為60時，時單元的內容加1，記數緩沖區復位。
為了在led管上顯示時分秒，可將計數緩沖區的時分秒送入到顯示緩沖區中，通過拆查表數換碼輸出顯示，從而構成數字電子鍾。
4．實驗原理圖
5．實驗源程序
中斷入口程序
org 0000h ;程序執行開始地址
ljmp start ;跳到標號start執行
org 0003h ;外中斷0中斷程序入口
reti ;外中斷0中斷返回
org 000bh ;定時器t0中斷程序入口
ljmp intt0 ;跳至intto執行
org 0013h ;外中斷1中斷程序入口
reti ;外中斷1中斷返回
org 001bh ;定時器t1中斷程序入口
ljmp intt1 ;跳至intt1執行
org 0023h ;串列中斷程序入口地址
reti ;串列中斷程序返回
;; 主 程 序 ;;
start: clr p2.1
setb p2.0
mov r0,#70h ;清70h-7ah共11個內存單元
mov r7,#0bh ;
cleardisp: mov @r0,#00h ;
inc r0 ;
djnz r7,cleardisp ;
mov 20h,#00h ;清20h（標志用）
mov 7ah,#0ah ;放入"熄滅符"數據
mov tmod,#11h ;設t0、t1為16位定時器
mov tl0,#0b0h ;50ms定時初值（t0計時用）
mov th0,#3ch ;50ms定時初值
mov tl1,#0b0h ;50ms定時初值（t1閃爍定時用）
mov th1,#3ch ;50ms定時初值
setb ea ;總中斷開放
setb et0 ;允許t0中斷
setb tr0 ;開啟t0定時器
mov r4,#14h ;1秒定時用初值（50ms×20）
start1: lcall display ;調用顯示子程序
jnb p3.2,setmm1 ;p3.2口為0時轉時間調整程序
sjmp start1 ;p3.2口為1時跳回start1
setmm1: ljmp setmm ;轉到時間調整程序setmm
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 1秒計時程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;t0中斷服務程序
intt0: push acc ;累加器入棧保護
push psw ;狀態字入棧保護
clr et0 ;關t0中斷允許
clr tr0 ;關閉定時器t0
mov a,#0b7h ;中斷響應時間同步修正
add a,tl0 ;低8位初值修正
mov tl0,a ;重裝初值（低8位修正值）
mov a,#3ch ;高8位初值修正
addc a,th0 ;
mov th0,a ;重裝初值（高8位修正值）
setb tr0 ;開啟定時器t0
djnz r4, outt0 ;20次中斷未到中斷退出
addss: mov r4,#14h ;20次中斷到（1秒）重賦初值
mov r0,#71h ;指向秒計時單元（71h-72h）
acall add1 ;調用加1程序（加1秒操作）
mov a,r3 ;秒數據放入a（r3為2位十進制數組合）
clr c ;清進位標志
cjne a,#60h,addmm ;
addmm: jc outt0 ;小於60秒時中斷退出
acall clr0 ;大於或等於60秒時對秒計時單元清0
mov r0,#77h ;指向分計時單元（76h-77h）
acall add1 ;分計時單元加1分鍾
mov a,r3 ;分數據放入a
clr c ;清進位標志
cjne a,#60h,addhh ;
addhh: jc outt0 ;小於60分時中斷退出
acall clr0 ;大於或等於60分時分計時單元清0
mov r0,#79h ;指向小時計時單元（78h-79h）
acall add1 ;小時計時單元加1小時
mov a,r3 ;時數據放入a
clr c ;清進位標志
cjne a,#24h,hour ;
hour: jc outt0 ;小於24小時中斷退出
acall clr0 ;大於或等於24小時小時計時單元清0
outt0: mov 72h,76h ;中斷退出時將分、時計時單元數據移
mov 73h,77h ;入對應顯示單元
mov 74h,78h ;
mov 75h,79h ;
pop psw ;恢復狀態字（出棧）
pop acc ;恢復累加器
setb et0 ;開放t0中斷
reti ;中斷返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 閃動調時 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;t1中斷服務程序，用作時間調整時調整單元閃爍指示
intt1: push acc ;中斷現場保護
push psw ;
mov tl1, #0b0h ;裝定時器t1定時初值
mov th1, #3ch ;
djnz r2,intt1out ;0.3秒未到退出中斷（50ms中斷6次）
mov r2,#06h ;重裝0.3秒定時用初值
cpl 02h ;0.3秒定時到對閃爍標志取反
jb 02h,flash1 ;02h位為1時顯示單元"熄滅"
mov 72h,76h ;02h位為0時正常顯示
mov 73h,77h ;
mov 74h,78h ;
mov 75h,79h ;
intt1out: pop psw ;恢復現場
pop acc ;
reti ;中斷退出
flash1: jb 01h,flash2 ;01h位為1時，轉小時熄滅控制
mov 72h,7ah ;01h位為0時，"熄滅符"數據放入分
mov 73h,7ah ;顯示單元（72h-73h），將不顯示分數據
mov 74h,78h ;
mov 75h,79h ;
ajmp intt1out ;轉中斷退出
flash2: mov 72h,76h ;01h位為1時，"熄滅符"數據放入小時
mov 73h,77h ;顯示單元（74h-75h），小時數據將不顯示
mov 74h,7ah ;
mov 75h,7ah ;
ajmp intt1out ;轉中斷退出
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 加1子 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
add1: mov a,@r0 ;取當前計時單元數據到a
dec r0 ;指向前一地址
swap a ;a中數據高四位與低四位交換
orl a,@r0 ;前一地址中數據放入a中低四位
add a,#01h ;a加1操作
da a ;十進制調整
mov r3,a ;移入r3寄存器
anl a,#0fh ;高四位變0
mov @r0,a ;放回前一地址單元
mov a,r3 ;取回r3中暫存數據
inc r0 ;指向當前地址單元
swap a ;a中數據高四位與低四位交換
anl a,#0fh ;高四位變0
mov @r0,a ;數據放入當削地址單元中
ret ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 清零程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;對計時單元復零用
clr0: clr a ;清累加器
mov @r0,a ;清當前地址單元
dec r0 ;指向前一地址
mov @r0,a ;前一地址單元清0
ret ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 時鍾調整程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;當調時按鍵按下時進入此程序
setmm: clr et0 ;關定時器t0中斷
clr tr0 ;關閉定時器t0
lcall dl1s ;調用1秒延時程序
jb p3.2,closedis ;鍵按下時間小於1秒，關閉顯示（省電）
mov r2,#06h ;進入調時狀態，賦閃爍定時初值
setb et1 ;允許t1中斷
setb tr1 ;開啟定時器t1
set2: jnb p3.2,set1 ;p3.7口為0（鍵未釋放），等待
setb 00h ;鍵釋放，分調整閃爍標志置1
set4: jb p3.2,set3 ;等待鍵按下
lcall dl05s ;有鍵按下，延時0.5秒
jnb p3.2,sethh ;按下時間大於0.5秒轉調小時狀態
mov r0,#77h ;按下時間小於0.5秒加1分鍾操作
lcall add1 ;調用加1子程序
mov a,r3 ;取調整單元數據
clr c ;清進位標志
cjne a,#60h,hhh ;調整單元數據與60比較
hhh: jc set4 ;調整單元數據小於60轉set4循環
lcall clr0 ;調整單元數據大於或等於60時清0
clr c ;清進位標志
ajmp set4 ;跳轉到set4循環
closedis: setb et0 ;省電（led不顯示）狀態。開t0中斷
setb tr0 ;開啟t0定時器（開時鍾）
close: jb p3.2,close ;無按鍵按下，等待。
lcall display ;有鍵按下，調顯示子程序延時削抖
jb p3.2,close ;是干擾返回close等待
waith: jnb p3.2,waith ;等待鍵釋放
ljmp start1 ;返回主程序（led數據顯示亮）
sethh: clr 00h ;分閃爍標志清除（進入調小時狀態）
sethh1: jnb p3.2,set5 ;等待鍵釋放
setb 01h ;小時調整標志置1
set6: jb p3.2,set7 ;等待按鍵按下
lcall dl05s ;有鍵按下延時0.5秒
jnb p3.2,setout ;按下時間大於0.5秒退出時間調整
mov r0,#79h ;按下時間小於0.5秒加1小時操作
lcall add1 ;調加1子程序
mov a,r3 ;
clr c ;
cjne a,#24h,houu ;計時單元數據與24比較
houu: jc set6 ;小於24轉set6循環
lcall clr0 ;大於或等於24時清0操作
ajmp set6 ;跳轉到set6循環
setout: jnb p3.2,setout1 ;調時退出程序。等待鍵釋放
lcall display ;延時削抖
jnb p3.2,setout ;是抖動，返回setout再等待
clr 01h ;清調小時標志
clr 00h ;清調分標志
clr 02h ;清閃爍標志
clr tr1 ;關閉定時器t1
clr et1 ;關定時器t1中斷
setb tr0 ;開啟定時器t0
setb et0 ;開定時器t0中斷（計時開始）
ljmp start1 ;跳回主程序
set1: lcall display ;鍵釋放等待時調用顯示程序（調分）
ajmp set2 ;防止鍵按下時無時鍾顯示
set3: lcall display ;等待調分按鍵時時鍾顯示用
ajmp set4
set5: lcall display ;鍵釋放等待時調用顯示程序（調小時）
ajmp sethh1 ;防止鍵按下時無時鍾顯示
set7: lcall display ;等待調小時按鍵時時鍾顯示用
ajmp set6
setout1: lcall display ;退出時鍾調整時鍵釋放等待
ajmp setout ;防止鍵按下時無時鍾顯示
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 顯示程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 顯示數據在70h-75h單元內，用六位led共陽數碼管顯示，p1口輸出段碼數據，p3口作
; 掃描控制，每個led數碼管亮1ms時間再逐位循環。
display: mov r1,#70h ;指向顯示數據首址
mov r5,#0fbh ;掃描控制字初值
play: mov a,r5 ;掃描字放入a
mov p2,a ;從p3口輸出
clr p2.1
mov a,@r1 ;取顯示數據到a
mov dptr,#tab ;取段碼表地址
movc a,@a+dptr ;查顯示數據對應段碼
mov p0,a ;段碼放入p1口
lcall dl1ms ;顯示1ms
inc r1 ;指向下一地址
mov a,r5 ;掃描控制字放入a
jnb acc.7,endout ;acc.5=0時一次顯示結束
rl a ;a中數據循環左移
mov r5,a ;放回r5內
ajmp play ;跳回play循環
endout: setb p2.7 ;一次顯示結束，p3口復位
mov p0,#0ffh ;p1口復位
ret ;子程序返回
tab: db 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h,0ffh
;共陽段碼表 "0""1""2" "3""4""5""6""7" "8""9""不亮"
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 延時程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1ms延時程序，led顯示程序用
dl1ms: mov r6,#14h
dl1: mov r7,#19h
dl2: djnz r7,dl2
djnz r6,dl1
ret
;20ms延時程序，採用調用顯示子程序以改善led的顯示閃爍現象
ds20ms: acall display
acall display
acall display
ret
;延時程序，用作按鍵時間的長短判斷
dl1s: lcall dl05s
lcall dl05s
ret
dl05s: mov r3,#20h ;8毫秒*32=0.196秒
dl05s1: lcall display
djnz r3,dl05s1
ret
;
end ;程序結束
你看看這個時鍾程序吧 ，