LRA電路

『壹』 51單片機做數字電子鍾

源程序如下： ORG 0000H ;程序開始入口

LJMP START

ORG 0003H ;外中斷0中斷程序入口

RETI

ORG 000BH ;定時器T0中斷程序入口

LJMP INTT0 ;跳至INTTO執行

ORG 0013H ;外中斷1中斷程序入口

RETI

ORG 001BH ;定時器T1中斷程序入口

LJMP INTT1

ORG 0023H ;串列中斷程序入口地址

RETI

;---------------主程序----------------------;

START:MOV R0,#70H ;70給R0,清70-7FH顯示內存

MOV R7,#0FH

CLEARDISP:MOV @R0,#00H ;0給R0中的數為地址的內存中存放(70H)

INC R0

DJNZ R7,CLEARDISP

MOV 78H,#2 ;默認時間為12:00,鬧鍾5:00

MOV 79H,#1

MOV 74H,#2 ;防止上電時數碼管顯示00小時

MOV 75H,#1

MOV 66H,#1 ;中斷退出時66H為1時,分、時計時單元數據移入顯存標志

MOV 68H,#1 ;上電默認鬧鍾開狀態

MOV 7DH,#6 ;鬧鍾時十位

MOV 7CH,#3

MOV 69H,#0

MOV 7AH,#0AH ;放入"熄滅符"數據

MOV TMOD,#11H ;設T0、T1為16位定時器

MOV TL0,#0B0H ;50MS定時初值（T0計時用）

MOV TH0,#3CH

SETB EA ;總中斷開放

SETB ET0 ;允許T0中斷

SETB TR0 ;T0定時器開始計時

MOV R4,#14H ;1秒定時用初值（50MS×20）

START1:LCALL DISPLAY ;顯示子程序

LCALL BEEP ;鬧鍾查詢

JNB P1.7,SETTIME ;P1.7口為0時轉時間調整程序

JMP START1 ;P1.7口為1時跳回START1

;-----------------------時間鬧鍾調整系統--------------------------;

NFLAG:MOV A,68H ;設置鬧鍾開關狀態

CJNE A,#1,BEE68

MOV 68H,#0

JMP E6

BEE68:MOV 68H,#1

E6:MOV 66H,#8 ;中斷退出66H不為1時分、時計時單元數據移入顯存標志

MOV 72H,7BH

MOV 73H,7CH

MOV 74H,7DH

MOV 75H,7EH

LCALL DDL

LCALL DDL

MOV 72H,68H

MOV 73H,69H

MOV 74H,7AH

MOV 75H,7AH

LCALL DDL

LCALL DDL

MOV 66H,#1

LJMP START1

SETTIME:LCALL DDL

JB P1.7,NFLAG ;鍵按下時間小於1秒，設置鬧鍾開關狀態並查看鬧鍾時間,不關走時,確保准確,大於1秒調時

MOV TL1,#0B0H ;T1閃爍定時初值

MOV TH1,#3CH

MOV R2,#06H ;進入調時狀態，賦閃爍定時初值

MOV 66H,#8 ;調鬧鍾時保持走時,關閉時鍾顯示數據

SETB ET1 ;允許T1中斷

SETB TR1 ;開啟定時器T1

SET1:LCALL DISPLAY ;調用顯示,防止鍵按下無顯示

JNB P1.7,SET1 ;P1.7口為0等待鍵釋放

MOV R5,#00H ;清設置類型閃爍標志

SETN1:INC R5 ;鬧鍾分調整

SET5:LCALL DISPLAY

JB P1.7,SET5

SEETN1:LCALL DDL ;有鍵按下大於1秒分時間連續加(0.5秒加1),小於1秒轉調時狀態

JB P1.7,SET6 ;鍵釋放查詢,鍵釋放自動轉調時

MOV R0,#7CH

LCALL ADD1

MOV A,R3

CLR C

CJNE A,#60H,HHN1

HHN1:JC SEETN1

LCALL CLR0

JMP SEETN1

SET6:INC R5 ;鬧鍾時調整

SEET6:LCALL DISPLAY

JB P1.7,SEET6

SEETNH1:LCALL DDL

JB P1.7,SETF

MOV R0,#7EH

LCALL ADD1

MOV A,R3

CLR C

CJNE A,#24H,HOUU1

HOUU1:JC SEETNH1

LCALL CLR0

JMP SEETNH1

SETF:LCALL DISPLAY

JB P1.7,SETF

LCALL DDL

JNB P1.7,SETOUT ;短按調時,長按退出

CLR ET0

CLR TR0

MOV 70H,#00H ;設定後的時間從00秒開始走時

MOV 71H,#00H

INC R5

SET3:LCALL DISPLAY

JB P1.7,SET3

SETMM:LCALL DDL

JB P1.7,SET4

MOV R0,#77H

LCALL ADD1

MOV A,R3

CLR C

CJNE A,#60H,MMH

MMH:JC SETMM

LCALL CLR0

AJMP SETMM

SET4:INC R5

SEET4:LCALL DISPLAY

JB P1.7,SEET4

SETHH:LCALL DDL

JB P1.7,SETOUT1

MOV R0,#79H

LCALL ADD1

MOV A,R3

CLR C

CJNE A,#24H,HOUU

HOUU:JC SETHH

LCALL CLR0

AJMP SETHH

SETOUT1:SETB ET0

SETB TR0 ;計時開始

SETOUT:MOV R5,#00H ;清設置類型閃爍標志

CLR TR1 ;關閉T1

CLR ET1 ;關T1中斷

MOV 66H,#1

SETOUT2:LCALL DISPLAY

JNB P1.7,SETOUT2

LJMP START1

;--------------------------延時1秒鍾-----------------------;

DDL:MOV 18H,#36

DDL0:MOV 17H,#239

DDL1:LCALL DISPLAY

DJNZ 17H,DDL1

DJNZ 18H,DDL0

RET

;----------------------------T0中斷程序------------------------;

INTT0: PUSH ACC ;打包

PUSH PSW

CLR ET0

CLR TR0

MOV A,#0B7H

ADD A,TL0

MOV TL0,A

MOV A,#3CH

ADDC A,TH0

MOV TH0,A

SETB TR0

DJNZ R4, OUTT0 ;20次中斷未到中斷退出

ADDSS: MOV R4,#14H ;20次中斷到（1秒）重賦初值

MOV R0,#71H ;指向秒計時單元（70-71H）

ACALL ADD1 ;調用加1程序（加1秒操作）

MOV A,R3 ;秒數據放入A（R3為2位十進制數組合）

CLR C ;清進位標志

CJNE A,#60H,ADDMM

ADDMM: JC OUTT01 ;小於60秒退出

ACALL CLR0 ;等於或大於60秒清0

MOV R0,#77H ;指向分計時單元（76H-77H）

ACALL ADD1

MOV A,R3

CLR C

CJNE A,#60H,ADDHH

ADDHH: JC OUTT0

ACALL CLR0

MOV R0,#79H ;指向小時計時單元（78H-79H）

ACALL ADD1

MOV A,R3

CLR C

CJNE A,#24H,HOUR

HOUR: JC OUTT0

ACALL CLR0

OUTT0: MOV A,66H ;查詢標志

CJNE A,#1,OUTT01

MOV 72H,76H ;中斷退出時將分、時計時單元數據移入對應顯示單元

MOV 73H,77H

MOV 74H,78H

MOV 75H,79H

OUTT01:POP PSW ;出棧

POP ACC

SETB ET0 ;開放T0

RETI ;中斷返回

;---------------------------加1程序--------------------------;

ADD1: MOV A,@R0 ;取當前計時單元數據到A

DEC R0 ;指向前一地址

SWAP A ;A中數據高四位與低四位交換

ORL A,@R0 ;前一地址中數據放入A中低四位

ADD A,#01H ;A加1操作

DA A ;十進制調整

MOV R3,A ;移入R3寄存器

ANL A,#0FH ;高四位變0

MOV @R0,A ;放回前一地址單元

MOV A,R3 ;取回R3中暫存數據

INC R0 ;指向當前地址單元

SWAP A ;A中數據高四位與低四位交換

ANL A,#0FH ;高四位變0

MOV @R0,A ;數據放入當削地址單元中

RET

CLR0: CLR C

CLR A ;清累加器

MOV @R0,A ;清當前地址單元

DEC R0 ;指向前一地址

MOV @R0,A ;前一地址單元清0

RET ;子程序返回

;-------------------------調時閃爍程序----------------------;

INTT1: PUSH ACC

PUSH PSW

MOV TL1,#0B0H

MOV TH1,#3CH

DJNZ R2,INTT1OUT ;0.3秒未到退出中斷（50MS中斷6次）

MOV R2,#06H ;重裝0.3秒定時用初值

CPL 02H ;0.3秒定時到對閃爍標志取反

JB 02H,FLASH1 ;02H位為1時顯示單元"熄滅"

MOV A,R5

CJNE A,#01H,NL

JMP NNN1

NL:CJNE A,#02H,NL1

LJMP NNN1

NL1:CJNE A,#03H,NL2

LJMP NLL

NL2:CJNE A,#04H,INTT1OUT

LJMP NLL

NLL:MOV 72H,76H

MOV 73H,77H

MOV 74H,78H

MOV 75H,79H

AJMP INTT1OUT

NNN1:MOV 72H,7BH

MOV 73H,7CH

MOV 74H,7DH

MOV 75H,7EH

INTT1OUT:POP PSW ;恢復現場

POP ACC

RETI ;中斷退出

FLASH1:MOV A,R5

CJNE A,#01H,ML

LJMP MNN1

ML:CJNE A,#02H,ML1

LJMP MNN2

ML1:CJNE A,#03H,MN

LJMP MLL

MN:CJNE A,#04H,INTT1OUT

LJMP MHL

MLL:MOV 72H,7AH

MOV 73H,7AH ;顯示單元（72-73H），將不顯示分數據

MOV 74H,78H

MOV 75H,79H

AJMP INTT1OUT

MHL:MOV 72H,76H

MOV 73H,77H

MOV 74H,7AH ;顯示單元（74-75H），小時數據將不顯示

MOV 75H,7AH

AJMP INTT1OUT

MNN1:MOV 72H,7AH

MOV 73H,7AH ;顯示單元（72-73H），將不顯示鬧鍾分數據

MOV 74H,7DH

MOV 75H,7EH

AJMP INTT1OUT

MNN2:MOV 72H,7BH

MOV 73H,7CH

MOV 74H,7AH

MOV 75H,7AH ;顯示單元（74-75H），鬧鍾小時數據將不顯示

AJMP INTT1OUT

;-------------------------顯示-------------------------------;

DISPLAY:MOV DPTR,#DISDATA

MOV A,70H

MOVC A,@A+DPTR

MOV P3,A

CLR P1.0

NOP

NOP

NOP

SETB P1.0

MOV A,71H

MOVC A,@A+DPTR

MOV P3,A

CLR P1.1

NOP

NOP

NOP

SETB P1.1

MOV A,72H

MOVC A,@A+DPTR

MOV P3,A

CLR P1.2

NOP

NOP

NOP

SETB P1.2

MOV A,73H

MOVC A,@A+DPTR

MOV P3,A

CLR P1.3

NOP

NOP

NOP

SETB P1.3

MOV A,74H

MOVC A,@A+DPTR

MOV P3,A

CLR P1.4

NOP

NOP

NOP

SETB P1.4

MOV A,75H

MOVC A,@A+DPTR

MOV P3,A

CLR P1.5

NOP

NOP

NOP

SETB P1.5

RET

BEEP:MOV A,68H ;查詢標志

CJNE A,#1,BEERE

MOV A,78H ;查詢鬧鍾時個位

CJNE A,7DH,BEERE

MOV A,79H ;查詢鬧鍾時十位

CJNE A,7EH,BEERE

MOV A,76H ;查詢鬧鍾分個位

CJNE A,7BH,BEERE

MOV A,77H ;查詢鬧鍾分十位

CJNE A,7CH,BEERE

BB:CLR P1.6

LCALL DDL

SETB P1.6

LCALL DDL

JNB P1.7,BEERR

BEERE:RET

BEERR:SETB P1.6

MOV 68H,#0

LCALL DISPLAY

JNB P1.7,BEERR

JMP BEERE

DISDATA:DB 0C0H,0F9H,64H,70H,59H,52H,42H,0F8H,40H,50H,0FFH ;0123456789空白

END

『貳』 在「描繪小電珠的伏安特性曲線」的實驗中備有下列器材：A．小燈泡（3.8V，1.5W）  ...

（1）由於伏安特性曲線中的電壓和電流均要從零開始測量，所以滑動變阻器應選用回分壓式，分壓式接答法適用於測量較大阻值電阻（與滑動變阻器的總電阻相比）；小燈泡電阻R_L=

『叄』 試分析全橋、半橋和推挽電路中的開關和整流二極體在工作中承受的最大電壓、最大電流和平均電流。

http://wenku..com/link?url=-_-_r-2fLQi

『肆』 四個輸入高電平，才輸出高電平的門電路

一、四輸入端與門：74LS21 。
http://wenku..com/link?url=_srdMqEIXq__5Q19t9VSW
二、74LS00 是最普通的器件，到處都有，用不著誰代替。
三、12V不能接入 TTL 器件，用 CMOS 器件即可。
四、NE55 電源電壓范圍很寬，選用與數字電路一致的電源電壓即可。3腳用1K電阻接 Vcc （上拉電阻），再接入數字電路輸入端。
TTL 器件已經被 CMOS 取代，學校教學用來學習基礎知識而已，實用要選擇 CMOS 晶元。

『伍』 電腦屏幕顯示的看不懂 幫忙看下

A7599AMS V1.4 091809
的AMD Athlon(tm)X三435處理器
ddr3 DRAM頻率(unganged 64位模式1133)。
1 amd北大橋,啟c2)
contrillers….done初始化usb……
2048mb好
ide prinmary主人…自動監測。Aiapi印刷專電路板屬。
sataz…自動硬碟
基本掌握:索尼可Ide ddv1678a 1.60
超直接存儲器存取mode-2
wd500aaks-dov1ao Sata2:wdc 05.01d05
Vtlra直接存儲器存取mode-6,s.m.a.r.t和狀態良好
usb海量存儲decices自動…。
大眾strorage裝置時發現,萬用串列匯流排的配置
COMS設置錯誤
Coms探測器/時間不確定的
按下f1鍵來運行安裝程序
按f2負荷默認值和繼續
F11進入引

『陸』 我家電腦有時不能開機開機是黑屏 但主機有聲音不是顯示器問題有時可以開機我才換的配置。是不是不兼容啊！

內存沒插好吧..或是散熱不好
另外,超頻的最好恢復下

『柒』 保險絲是用______、______的鉛銻合金製成的

保險絲的作用是電路中電流過大時自動熔斷，可見熔點一定要低；另外其利用了電流的熱效應，一定容易發熱，則一定要有較大的電阻率．
故答案為：電阻率大；熔點低．

『捌』 haslra充電寶怎麼樣

充電寶主要由電芯、電路保護板和外殼組成，組成結構都大同小異，所以充電寶的質量也都差不多，都是大同小異的，只是外觀和形狀有所差異。，不過好不好還得自己用過才知道，只要電芯不是劣質的就行。

『玖』 請熟悉電力專業英文的人幫忙翻譯一下(3)！！！！！

2-2正常電流
正常電流或者說是帶載電流被定義為在正常操作環境下的設計電流。正常電流可能根據負載的特性從輕載到滿載時發生變化。電機就是個最好的例子，電機電流從小值（輕載）到中值（中載）到最大值（滿載）。最大負載時的電流被稱為滿載電流也被叫做FLA（滿載安培數）一般在名牌上寫明。另外，正常電流只出現在一般電路里。正常電路包含相線和零線。一般不包括設備接地導體線。
2 過載電流
過載電流一般出現在一般電路中且超過滿載電流很多倍。一般過載電流被認為是不正常的電流，產生的原因是設備過載，電壓過低，單項運行。有一些電流例如電機啟動電流是暫時性的所以被視為正常電流。電機電流取決於設計方法，在一些極端情況電機電流可能超過20倍滿載電流。電機啟動電流被稱為堵轉電流用LRA（Locked rator amperes）在名牌上表示。一般情況下過載電流遠大於正常電流且小於堵轉電流且只出現在一般電路里。
2-4 短路電流
短路電流一般大於堵轉電流甚至達到上千安培。短路電流被限制在系統最大短路電流。短路電流被更深入的分為連接型和拉弧型。
a 連接型的短路電流引起的原因是相線連接在一起。這也許是不正確的連接或者金屬物體作為連接體位於兩項之間。顯然大量的短路電流將流入短路連接的故障點。
b 拉弧型短路電流。拉弧型短路電流是由於相線沒有完全的連接到一起。這種情況往往是絕緣問題和連接松動造成的。在這種情況下電弧做為維持電流通過松動部分是必然的。電弧作為阻抗，拉弧故障點的電流值要小於連接型短路故障點。